[amel27]

Lodoss, если без подкаталогов, то просто:

Код:

#Include <File.au3>

$sFPath = @WindowsDir
$aFiles = _FileListToArray($sFPath, '*', 1)
$iFiles = $aFiles[0]

MsgBox(64, "Результат", 'В папке "'& $sFPath & '" найдено '& $iFiles &' файлов.')

[Lodoss]

Благодарю ! А если с подкаталогами ? Думаю тоже пригодится.

[Lodoss]

Если папка пуста, вылетает ошибка Можно как нибудь её обойти ?

[amel27]

Если папка пуста, вылетает ошибка »

Код:

#Include <File.au3>

$sFPath = @WindowsDir
$aFiles = _FileListToArray($sFPath, '*', 1)
$iFiles = 0

If IsArray($aFiles) Then $iFiles = $aFiles[0]
MsgBox(64, "Результат", 'В папке "'& $sFPath & '" найдено '& $iFiles &' файлов.')

А если с подкаталогами ? Думаю тоже пригодится. »

тут много вариантов можно напридумать:

Код:

#Include <File.au3>

$sFPath = @WindowsDir
$iFiles = _FilesInFolder($sFPath)

MsgBox(64, "Результат", 'В папке "'& $sFPath & '" найдено '& $iFiles &' файлов.')

Func _FilesInFolder($sRoot)
    Local $aFolders = _FileListToArray($sRoot,'*', 2)
    Local $aFiles = _FileListToArray($sRoot,'*', 1), $iCount=0
    If IsArray($aFolders) Then
        For $i=1 To $aFolders[0]
            $iCount+= _FilesInFolder($sRoot &"\"& $aFolders[$i])
        Next
    EndIf
    If IsArray($aFiles) Then $iCount += $aFiles[0]
    Return $iCount
EndFunc

[Lodoss]

Большущее спасибо !!! А то массивы ну никак не могу победить

[amel27]

А то массивы ну никак не могу победить »

ИМХО это недоработка _FileListToArray(), т.к. пустая папка - нормальная ситуация, а не ошибочная, т.е. UDF в этом случае должна возвращать пустой массив... иначе, зачем было вообще заморачиваться массивом со счетчиком?

[Diamond]

Lodoss, Можно ещё так:

Код:

$aInfo = DirGetSize(@WindowsDir, 1)
MsgBox(0,@WindowsDir,"Общий размер: " & Round($aInfo[0]/1024^2) & " MB" & @LF & _
"Кол-во файлов: " & $aInfo[1] & @LF & _
"Кол-во папок: " & $aInfo[2])

[Yoxcel]

Не стал создавать новую тему, так как вопрос, кажется, похожий, но чуть посложней.
Пытался написать скрипт, создающий древовидный список папок и файлов, но мозги закипают и ничего не выходит, кроме "вылетания" скрипта с ошибкой или неверного результата. Понятно, что надо использовать рекурсию, но пока до конца не разобрался.
Может, у кого есть готовое решение? :-)

[Iska]

Yoxcel, можно, конечно, и «FileFindFirstFile/FileFindNextFile», однако в этом случае, на мой взгляд, самое простое — пользовать не средства AutoIt, а библиотеку «Scripting.FileSystemObject»:

Код:

$objFSO = ObjCreate("Scripting.FileSystemObject")

и делать сие по полной аналогии с известными скриптами vbscript:

Код:

Local Const $DriveTypeFixed = 2

Local $objFSO
Local $objDrive


$objFSO = ObjCreate("Scripting.FileSystemObject")

For $objDrive In $objFSO.Drives()
	If $objDrive.DriveType = $DriveTypeFixed Then
		ScanFolders($objDrive.RootFolder)
	EndIf
Next

$objFSO = ""

Exit(0)
;=============================================================================

;=============================================================================
Func ScanFolders($objFolder)
	Local $objSubFolder
	Local $objFile

	; Перебирать можно как в нисходящей…
	ConsoleWrite("[" & $objFolder.Path & "]" & @CRLF)

	For $objFile In $objFolder.Files
		ConsoleWrite($objFile.Name & @CRLF)
	Next

	For $objSubFolder In $objFolder.SubFolders
		ScanFolders($objSubFolder)
	Next

	; …так и в восходящей последовательности.
	;ConsoleWrite("[" & $objFolder.Path & "]" & @CRLF)
	;
	;For $objFile In $objFolder.Files
	;	ConsoleWrite($objFile.Name & @CRLF)
	;Next
EndFunc
;=============================================================================

добирая недостающий функционал уже средствами самого AutoIt.

читать дальше »

Я часто удивляюcь, почему столь нередко забывают и обходят стороной одно из самых выдающихся достижений AutoIt — использование Automation.