VBS/WSH/JS - [решено] скрипт с завершением сеанса определенного пользователя

amel27 · Отправлено: **12:30, 02-03-2009** | #2

убить заданную сессию можно через штатную утилиту rwinsta, пример:

Код:

rwinsta 5 /server:MyServer

здесь "5" - номер сессии, список сессий можно получить аналогично:

Код:

qwinsta /server:MyServer

понятно, что "убить" сессию и осуществить "выход из системы" с закрытием всех программ - вещи разные, но мне неизвестны способы удаленного завершения чужих сессий... по идее, подключаться к терминальной сессии и запускать в ней любую программу должна уметь PsExec (ключ "-i"), но мне не удалось этого добиться, и судя по форуму поддержки я такой не один

Как вариант: вставить при логоне запуск скрипта, который будет крутиться в фоне каждой сессии и делать "выход" по заданному условию (файл, ключ реестра, etc.)

hse2000 · Отправлено: **17:35, 02-03-2009** | #3

Тогда назревает вопрос, а можно ли пользователю приклеить статичный sessionid или sessionname?

amel27 · Отправлено: **12:39, 04-03-2009** | #4

по памяти ошибся, сегодня на работе получилось вот что (с XP-RU проверил):

Код:

@Echo Off

Set SERVER=MyServer
Set KILLME=Администратор

For /F "Tokens=1,2 Skip=3 Delims= " %%i In ('qwinsta /Server:%SERVER%') Do If "%%i"=="%KILLME%" rwinsta %%j /Server:%SERVER%

hse2000 · Отправлено: **18:01, 06-03-2009** | #5

вообщем вот что получается, если батник выглядит так

Код:

Set SERVER=2003test
Set KILLME=test1

For /F "Tokens=1,2 Skip=3 Delims= " %%i In ('qwinsta /Server:%SERVER%') Do If "%%i"=="%KILLME%" rwinsta %%j /Server:%SERVER%

,
test1 - имя юзера то имеем

Код:

C:\Documents and Settings\Administrator>Set SERVER=2003test

C:\Documents and Settings\Administrator>Set KILLME=test1

C:\Documents and Settings\Administrator>For /F "Tokens=1,2 Skip=3 Delims= " %i I
n ('qwinsta /Server:2003test') Do If "%i" == "test1" rwinsta %j /Server:2003test


C:\Documents and Settings\Administrator>If "rdp-tcp#8" == "test1" rwinsta test1
/Server:2003test

C:\Documents and Settings\Administrator>

видно, что rwinsta берет, не имя сессии, а имя юзера.

Если меняем %j на %i, то получается все правильно

Код:

C:\Documents and Settings\Administrator>C:\test\3.bat

C:\Documents and Settings\Administrator>Set SERVER=2003test

C:\Documents and Settings\Administrator>Set KILLME=test1

C:\Documents and Settings\Administrator>For /F "Tokens=1,2 Skip=3 Delims= " %i I
n ('qwinsta /Server:2003test') Do If "%i" == "test1" rwinsta %i /Server:2003test


C:\Documents and Settings\Administrator>If "rdp-tcp#8" == "test1" rwinsta rdp-tc
p#8 /Server:2003test

НО!!!!!! команда rwinsta тогда не отрабатывает.... пробовал до rwinsta писать goto на след. строчку, чтобы она выполнялась с новой строки, но тогда пишется session %i not found. Где может быть косяк?

Vadikan · Конфигурация компьютера

hse2000, используйте тег [code][/code], плиз.

amel27 · Отправлено: **13:29, 09-03-2009** | #7

Цитата hse2000:

видно, что rwinsta берет, не имя сессии, а имя юзера »

понятно - я пробовал на отключенных сессиях, на активных появляется долнительный столбец ID:

Код:

Set SERVER=2003test
Set KILLME=test1

For /F "Tokens=1-4 Skip=3 Delims=# " %%i In ('qwinsta /Server:%SERVER%') Do (
   If "%%i"=="rdp-tcp" (
      If "%%k"=="%KILLME%" rwinsta %%l /Server:%SERVER%
   ) Else (
      If "%%i"=="%KILLME%" rwinsta %%j /Server:%SERVER%
   )
)

hse2000 · Отправлено: **14:58, 10-03-2009** | #8

спасибо, все работает. Можно скриптик добавлять в коллекцию =

bazik83 · Отправлено: **21:21, 22-05-2010** | #9

Подскажите, как доработать скрипт если нужно отключить несколько пользователей?

amel27 · Отправлено: **06:09, 23-05-2010** | #10

Цитата bazik83:

если нужно отключить несколько пользователей »

Код:

@Echo Off

Call :KILLME server1 user1
Call :KILLME server1 user2

Exit /B

:KILLME
 For /F "Tokens=1-4 Skip=3 Delims=# " %%i In ('qwinsta /Server:%~1') Do (
 If /I "%%i"=="%~2" rwinsta %%j /Server:%~1
 If /I "%%k"=="%~2" If /I "%%i"=="rdp-tcp" rwinsta %%l /Server:%~1)
GoTo :EOF