[Grabber2006]

Vanadiy777, Qk3 пишет в том духе, что после 14 января 2020 года система доставки обновлений для Windows 7 самовыпиливается и прекращает своё существование, а это не так.

[Qk3]

выложите результат выполнения в командной строке (cmd.exe) от имени Администратора »

Результат:

C:\Users\User>bitsadmin /List /AllUsers /Verbose BITSADMIN version 3.0 [ 7.5.7601 ] BITS administration utility. (C) Copyright 2000-2006 Microsoft Corp. BITSAdmin is deprecated and is not guaranteed to be available in future versions of Windows. Administrative tools for the BITS service are now provided by BITS PowerShell cm dlets. Unable to connect to BITS - 0x80070422 Указанная служба не может быть запущена, поскольку она отключена или все связанные с ней устройства отключены.

Что делать дальше?

это не так »

А как правильно?

[bredych]

Поддержка Windows 7 закончилась 14 января 2020 г. »

так это ж мс закончил. А винда о том не знает, вот и ломится.. я так понимаю..

[Qk3]

вот и ломится.. »

Так как уже нет смысла в этом обращении, его можно как-то отключить?

[Vanadiy777]

Так как уже нет смысла в этом обращении, его можно как-то отключить? »

Qk3,
У Вас все обновления полностью отключены?

[Qk3]

Здесь, или еще где-то? > https://i.ibb.co/VwgMy50/obn.png

[Vanadiy777]

Здесь, или еще где-то? »

Qk3,
Да, здесь, вроде правильно все.

Я для отключения вот этот батник использую.

Скрытый текст

Код:

@echo off
cls
TITLE Центр обновления Windows
MODE CON COLS=57 LINES=8 
COLOR 47

call :Admin

:Admin
reg query "HKU\S-1-5-19\Environment" >nul 2>&1
if not %errorlevel% EQU 0 (
	cls
	rem powershell.exe -windowstyle hidden -noprofile "$shell = New-Object -ComObject Shell.Application;$shell.ShellExecute('%~s0', '', '', 'runas')"
	powershell.exe -windowstyle hidden -noprofile "Start-Process '%~dpnx0' -Verb RunAs"
	exit
)

:check
Ver | Find "5.0" >Nul && goto Message
Ver | Find "5.1." >Nul && goto Message
Ver | Find "5.2." >Nul && goto Message
Ver | Find "6.0." >Nul && goto Message
Ver | Find "6.1.7600" >Nul && goto Message
Ver | Find "6.1.7601" >Nul && goto install
Ver | Find "6.2." >Nul && goto Message
Ver | Find "6.3." >Nul && goto Message
Ver | Find "10.0." >Nul && goto Message

:install
cls
MODE CON COLS=64 LINES=13 
COLOR 47
echo.
echo  ╔════════════════════════════════════════════════════════════╗
echo  ║                                                            ║
echo  ║                                                            ║
echo  ║    Будет выполнено отключение Центра обновления Windows    ║
echo  ║                                                            ║
echo  ║      Для продолжения операции нажмите клавишу Пробел       ║
echo  ║                                                            ║
echo  ║       или просто закройте окно программы для отмены.       ║
echo  ║                                                            ║
echo  ║                                                            ║
echo  ╚════════════════════════════════════════════════════════════╝
pause >Nul

Reg Add "HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU" /v "NoAutoUpdate" /t REG_DWORD /d "1" /f
Reg Delete "HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU" /v "AUOptions" /f
Reg Add "HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU" /v "NoAutoRebootWithLoggedOnUsers" /t REG_DWORD /d "1" /f
Reg Delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /v "AUOptions" /f
Reg Delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /v "IncludeRecommendedUpdates" /f

cls
MODE CON COLS=57 LINES=7 
COLOR 47
echo.
echo.
echo    Операция успешно завершена.
echo.
echo    Нажмите любую клавишу . . .
echo.

pause >Nul

exit

:Message
cls
MODE CON COLS=57 LINES=7 
COLOR 47
echo.
echo.
echo.
echo    Эта версия операционной системы не поддерживается!
echo.
echo.
ping -n 5 127.0.0.1 >Nul
exit

[Qk3]

батник использую »

Очень интересный и нужный батничек! Большое спасибо!
Только для 7-ки, или и в 10-ке сработает?

Этот код пришлось перевести в 866 кодировку. Иначе вместо букв были кракозябры.

[Vanadiy777]

Только для 7-ки, »

Да, только для 7-ки.

Этот код пришлось перевести в 866 кодировку. Иначе вместо букв были кракозябры. »

Все правильно. Я не стал об этом писать, думал, что Вы знаете, что если кириллица, то кодировку надо менять.

[Qk3]

Большое спасибо! Да, я знал какая кодировка используется в батниках. Написал потому, что возможно кто-то не знает это, но решит применить этот код.
-- не могу разобаться как прикрепить файл -- выложил здесь: https://easyupload.io/603t2r (Отключение обновления Windows 7.bat)

Да, только для 7-ки. »

Понял. Такой батник и для 10-11 был бы кстати.